Power Automate Desktopで全角文字を半角に変換する方法【PAD】

Power Automate Desktop(PAD)で全角文字を半角に変換する方法について解説します。

PADに全角⇔半角の変換アクションは用意されていない

PADには半角文字・全角文字の変換アクションは用意されていません。そのため、「VBScriptの実行」にて変換を行います。

「VBScript」とは、Windowsに標準搭載されているスクリプト言語で、JavaやPythonなどの一般のプログラミング言語のように環境構築する必要がなく、WindowsのPCであればVBScriptを実行することができます。

詳細は以下記事にて解説しています。

「VBScriptの実行」アクションの使い方

「VBScriptの実行」アクションを追加すると、以下のようなダイアログが表示されます。

この赤枠部分にスクリプトを書いていきます。

全角数字を半角数字にするスクリプト

全角数字を半角数字にするスクリプトです。こちらのスクリプトは、以下のサイトに載っていたものをそのまま使わせていただきました。

Windowsで無料で使えるPower Automate Desktopの利用方法⑥　全角数字を半角数字に変換したい

inp = "%NewVar%" 'NewVarをinpに格納する
out = ""'出力先outを初期化する
cnt = %NewVar.Length% 'NewVarの文字数を格納する
For lp = 1 to cnt		
buf = Mid(inp,lp,1) 'inpを先頭から１文字づつ取得し、bufに格納する。
Select Case buf		
Case "０": out = out & "0" 'bufが全角の「０」なら、半角の「0」を保存する
Case "１": out = out & "1" 'bufが全角の「１」なら ...
Case "２": out = out & "2"		
Case "３": out = out & "3"		
Case "４": out = out & "4"		
Case "５": out = out & "5"		
Case "６": out = out & "6"		
Case "７": out = out & "7"		
Case "８": out = out & "8"		
Case "９": out = out & "9"		
Case Else: out = out & buf 'bufが全角の「０」～「９」でなければ、元の１文字を保存する
End Select		
Next		
WScript.StdOut.Write(out) '編集が終わったoutを戻す

これを実行すると、元のテキストがDatetimeに変換されていることを確認できました。

半角カタカナを全角カタカナに変換するスクリプト

半角カタカナを全角カタカナに変換するスクリプトは以下になります。

' 半角カタカナから全角カタカナへの変換テーブル
Dim kanaConvMap
Set kanaConvMap = CreateObject("Scripting.Dictionary")
kanaConvMap.Add "ｱ", "ア"
kanaConvMap.Add "ｲ", "イ"
kanaConvMap.Add "ｳ", "ウ"
kanaConvMap.Add "ｴ", "エ"
kanaConvMap.Add "ｵ", "オ"
kanaConvMap.Add "ｶ", "カ"
kanaConvMap.Add "ｷ", "キ"
kanaConvMap.Add "ｸ", "ク"
kanaConvMap.Add "ｹ", "ケ"
kanaConvMap.Add "ｺ", "コ"
kanaConvMap.Add "ｻ", "サ"
kanaConvMap.Add "ｼ", "シ"
kanaConvMap.Add "ｽ", "ス"
kanaConvMap.Add "ｾ", "セ"
kanaConvMap.Add "ｿ", "ソ"
kanaConvMap.Add "ﾀ", "タ"
kanaConvMap.Add "ﾁ", "チ"
kanaConvMap.Add "ﾂ", "ツ"
kanaConvMap.Add "ﾃ", "テ"
kanaConvMap.Add "ﾄ", "ト"
kanaConvMap.Add "ﾅ", "ナ"
kanaConvMap.Add "ﾆ", "ニ"
kanaConvMap.Add "ﾇ", "ヌ"
kanaConvMap.Add "ﾈ", "ネ"
kanaConvMap.Add "ﾉ", "ノ"
kanaConvMap.Add "ﾊ", "ハ"
kanaConvMap.Add "ﾋ", "ヒ"
kanaConvMap.Add "ﾌ", "フ"
kanaConvMap.Add "ﾍ", "ヘ"
kanaConvMap.Add "ﾎ", "ホ"
kanaConvMap.Add "ﾏ", "マ"
kanaConvMap.Add "ﾐ", "ミ"
kanaConvMap.Add "ﾑ", "ム"
kanaConvMap.Add "ﾒ", "メ"
kanaConvMap.Add "ﾓ", "モ"
kanaConvMap.Add "ﾔ", "ヤ"
kanaConvMap.Add "ﾕ", "ユ"
kanaConvMap.Add "ﾖ", "ヨ"
kanaConvMap.Add "ﾗ", "ラ"
kanaConvMap.Add "ﾘ", "リ"
kanaConvMap.Add "ﾙ", "ル"
kanaConvMap.Add "ﾚ", "レ"
kanaConvMap.Add "ﾛ", "ロ"
kanaConvMap.Add "ﾜ", "ワ"
kanaConvMap.Add "ｦ", "ヲ"
kanaConvMap.Add "ﾝ", "ン"
' 拗音
kanaConvMap.Add "ｬ", "ャ"
kanaConvMap.Add "ｭ", "ュ"
kanaConvMap.Add "ｮ", "ョ"

' 長音
kanaConvMap.Add "ｰ", "ー"

' 濁点・半濁点付きカタカナへの変換ルール
kanaConvMap.Add "ｶﾞ", "ガ"
kanaConvMap.Add "ｷﾞ", "ギ"
kanaConvMap.Add "ｸﾞ", "グ"
kanaConvMap.Add "ｹﾞ", "ゲ"
kanaConvMap.Add "ｺﾞ", "ゴ"
kanaConvMap.Add "ｻﾞ", "ザ"
kanaConvMap.Add "ｼﾞ", "ジ"
kanaConvMap.Add "ｽﾞ", "ズ"
kanaConvMap.Add "ｾﾞ", "ゼ"
kanaConvMap.Add "ｿﾞ", "ゾ"
kanaConvMap.Add "ﾀﾞ", "ダ"
kanaConvMap.Add "ﾁﾞ", "ヂ"
kanaConvMap.Add "ﾂﾞ", "ヅ"
kanaConvMap.Add "ﾃﾞ", "デ"
kanaConvMap.Add "ﾄﾞ", "ド"
kanaConvMap.Add "ﾊﾞ", "バ"
kanaConvMap.Add "ﾋﾞ", "ビ"
kanaConvMap.Add "ﾌﾞ", "ブ"
kanaConvMap.Add "ﾍﾞ", "ベ"
kanaConvMap.Add "ﾎﾞ", "ボ"
kanaConvMap.Add "ﾊﾟ", "パ"
kanaConvMap.Add "ﾋﾟ", "ピ"
kanaConvMap.Add "ﾌﾟ", "プ"
kanaConvMap.Add "ﾍﾟ", "ペ"
kanaConvMap.Add "ﾎﾟ", "ポ"
kanaConvMap.Add "ｳﾞ", "ヴ"
kanaConvMap.Add "ｦﾞ", "ヺ"


' 入力文字列
inp = "%NewVar%" 'NewVarをinpに格納する
out = "" ' 出力文字列を初期化

For i = 1 To Len(inp)
    char = Mid(inp, i, 1)
    If i < Len(inp) Then nextChar = Mid(inp, i + 1, 1)

    If kanaConvMap.Exists(char) Then
        ' 半角カタカナの基本的な変換
        out = out & kanaConvMap(char)
        If nextChar = "ﾞ" Or nextChar = "ﾟ" Then
            ' 濁点または半濁点が次に来る場合は、変換を補正
            If nextChar = "ﾞ" Then
                out = Left(out, Len(out) - 1) & ChrW(AscW(Right(out, 1)) + 1) ' 濁音に変換
            ElseIf nextChar = "ﾟ" Then
                out = Left(out, Len(out) - 1) & ChrW(AscW(Right(out, 1)) + 2) ' 半濁音に変換
            End If
            i = i + 1 ' 濁点/半濁点をスキップ
        End If
    Else
        ' 半角カタカナ以外の文字はそのまま追加
        out = out & char
    End If
Next

' 結果を出力
WScript.StdOut.Write(out)

VBScriptの標準機能だけでは半角カタカナを全角カタカナに直接変換する関数は提供されていないので、カスタムの変換テーブルを作成し、手動で半角カタカナを全角カタカナにマッピングしています。

このフローを実行すると、

半角カタカナが全角カタカナに変換されました。

全角英字を半角英字に変換するスクリプト

全角英字を半角英字に変換するスクリプトは、以下のようになります。

' 入力文字列
inp = "%NewVar%" '
out = "" ' 出力文字列を初期化

' inpの長さを取得して、1文字ずつ処理
Dim i, c, code
For i = 1 To Len(inp)
    c = Mid(inp, i, 1)
    code = AscW(c)
    
    ' 全角英字（大文字）の場合
    If code >= &HFF21 And code <= &HFF3A Then
        out = out & ChrW(code - &HFF21 + &H41)
    ' 全角英字（小文字）の場合
    ElseIf code >= &HFF41 And code <= &HFF5A Then
        out = out & ChrW(code - &HFF41 + &H61)
    ' それ以外の文字はそのまま追加
    Else
        out = out & c
    End If
Next

' 結果を出力
WScript.StdOut.Write(out)

上記フローの実行結果は、以下のようになります。

全角英数字・記号を半角に変換するスクリプト

全角英数字・記号を半角に変換するスクリプトは以下になります。

' 入力文字列
inp = "%NewVar%"
out = "" ' 出力文字列を初期化

' inpの長さを取得して、1文字ずつ処理
Dim i, c, code
For i = 1 To Len(inp)
    c = Mid(inp, i, 1)
    code = AscW(c)
    
    ' 全角英数字または全角スペースの場合
    If (code >= &HFF01 And code <= &HFF5E) Then
        ' 全角記号・英数字を半角に変換
        out = out & ChrW(code - &HFF00 + &H20)
    ElseIf code = &H3000 Then
        ' 全角スペースを半角スペースに変換
        out = out & ChrW(&H20)
    Else
        ' それ以外の文字はそのまま追加
        out = out & c
    End If
Next

' 結果を出力
WScript.StdOut.Write(out)

上記フローの実行結果は、以下のようになります。

まとめ

今回は、Power Automate Desktop(PAD)で全角文字を半角に変換する方法について解説しました。

当ブログでは、Power Automate、Power Automate Desktopに関する記事を他にも投稿しています。もし、「このようなことが知りたい」「こんなフローの作り方が知りたい」等ございましたら、問い合わせやコメントからお気軽にご連絡ください。